#!/bin/csh
set n=$1    # station nr 1... in the order olmpp processes them
set e=$2    # users name from MyEmail, @... cut away
set site=NN
set model=NN
set tmp=$3  # 
if ( x$tmp == x ) set tmp=/home/loading/tmp


# Skip this for the GMT team to recreate the problem:
#set model = `awk '/MODEL: /{print $2}' olmpp.prt`
set spos = ( `awk '/Site:/{printf "%2.2f %2.2f\n", int($2*4)/4,int($3*4)/4}' $tmp/dump$n.dat` )
set r=`awk -v x=$spos[1] -v y=$spos[2] 'BEGIN{printf "%4.4f/%4.4f/%4.4f/%4.4f\n",x-1.625,x+1.875,y-1.625,y+1.875}'`
echo "plot-olmpp-dump :: Range r: $r"

set s=`awk  -v x=$spos[1] -v y=$spos[2] 'BEGIN{print x-0.5 "/" x+0.5 "/" y-0.5 "/" y+0.5}'`
echo "plot-olmpp-dump :: Range s: $s" 
set dx=`awk '/'$model'/{print $2}' ~/div/otm.margin`
set mapr=`echo $r | awk -F/ -v d=$dx '{print $1-d"/"$2+d"/"$3-d"/"$4+d}'`

gmt grdcut /home/loading/tide-models/netCDF/FES2004/amp.m2 -R$mapr -G$tmp/tmp.grd 
gmt grdmath $tmp/tmp.grd 900 LE 0 NAN = $tmp/mask.grd 
gmt grdmath $tmp/mask.grd 1.0 MUL = $tmp/tmp2.grd 

gmt psbasemap -R$r -JX4.5/4.5 -Ba0.5f0.05/a0.25f0.05WeSN -K >! $tmp/olmpp$n.ps
gmt grdview $tmp/tmp2.grd -K -O -R -JX -T+o0.5p,255+s -Cbackdrop.cpt >> $tmp/olmpp$n.ps

# Option -T+s+o<pen> ?? doesn't work. It did in GMT 4.5.3
# gmt grdview $tmp/tmp2.grd -K -O -R -JX -T+s+o0.2,255 -Cbackdrop.cpt
# 
# If we want the tiles outlined in white we must produce a grid made of lines
# like this:
#gmt grd2xyz $tmp/tmp2.grd | awk -v d=$dx '\! /NaN/{print $1,$2,3*d}' |\
#  gmt psxy  -R -JX -SS -K -O -W0.3,255 >> $tmp/olmpp$n.ps
#

awk '\!/Site:/{print $1,$2,1.5*$3}' $tmp/dump$n.dat |\
gmt psxy -R -JX -SS -K -O >> $tmp/olmpp$n.ps

awk '/Site:/{print $2,$3}' $tmp/dump$n.dat |\
gmt psxy -R -JX -K -O -W0.2,255/0/0 -Sx0.5 >> $tmp/olmpp$n.ps

awk '\!/Site:/{print $1,$2,5.25*$3}' $tmp/dump$n.dat |\
gmt psxy -R$s -JX4.5/4.5 -Ba0.25f0.05/a0.25f0.05wESN -SS -K -O -X5.2 >> $tmp/olmpp$n.ps

awk '/Site:/{print $2,$3}' $tmp/dump$n.dat |\
gmt psxy -R -JX -K -O -W0.2,255/0/0 -Sx0.5 >> $tmp/olmpp$n.ps

set site=`awk '/Site:/{sub(/Site:/,"",$1);sub(/\]/,"",$1);print $1}' $tmp/dump$n.dat`

pstext <<EOF -R0/10.7/0/4.5 -JX10.7/4.5 -X-5.2 -N -O >> $tmp/olmpp$n.ps
5.35 5.5 18 0 1 2 Ocean: $model  Station: $site  for $e
EOF

cd $tmp
ps2png -m -d 600x600 -o ~/www/PNG/${e}- olmpp$n.ps &

exit

